Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00024_Banner.ls

Text File | 2004-07-11 | 5.7 KB | 220 lines

--
--Banner
--

property ancestor

--sound banner properties
property bannerSprite
property bannerFieldCast
property bannerCastList
property delay

--these are the malleable properties of the banner
property bannerSndCast
property textHilite

global gPrinterB,gBannerartB,gLeftB,gSpeakerB,gHomeB,gHelpB,gRightB


on new me
  -- set constants:

  -- the sprite we will take over for animating
  set bannerSprite = gSpeakerB

  -- the number of the field cast member we will be refreshing
  set bannerFieldCast = "topBanner"

  -- the list of members we will be animating through
  set bannerCastList = ["speaker,1", "speaker,2", "speaker,3"]

  -- the color we will hilite the text in the field to be
  set textHilite = 134

  -- the delay between animated frames of the sound trumpet thingie
  set delay = 7

  -- initialize the ancestor:
  set ancestor = new (script "Dialog")

  -- do other initializations:

  return me
end


on destruct me
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end

--this will resolve the sprite number into a member number for a sound or an ID playback, and
--play back the sound.

--command = "#prompt", or "#ID"
on playSprite me, spr, command
  -- get all the info about that sprite
  -- just the number as it refers to that cast, not the absolute cast number
  set theMember = the memberNum of sprite spr

  -- the lib so that we can look elsewhere
  set theLib = the castlibNum of sprite spr

  -- the name of that lib
  set theLibName = the name of castLib theLib

  if command = #prompt then
    set targetLib = theLibName & " prompts"

    -- resolve this by name
    -- NOTE* this needs to be a unique name because it will end up playing the
    -- first sound that is called rootname

    if the type of member theMember of castLib targetLib = #sound then
      -- this sound must be called "...,prompt" because of the resolving routines in setupBanner
      set rootName = item 1 of (the name of member theMember of castLib targetLib)

      -- do the banner
      setUpBanner(me, rootName)
    end if

  else
    set targetLib = theLibName & " IDs"

    -- play back a sound
    if the type of member theMember of castLib targetLib = #sound then
      puppetSound member theMember of castLib targetLib
      updateStage

      -- wait for the sound to finish
      waitFXSound()
    else
      put "I could not find the ID sound"
    end if

  end if
end


-- key routine

on setupBanner me, newRootName, noPlay
  -- this looks for a sound called newRootName & ",prompt"
  -- and a text member called newRootName & ",txt"
  -- it puts a ref to both into the properties for this object, and then
  -- loads them into the on stage members

  -- we save the refs to the members
  set thisSound = the number of member (newRootName & ",prompt")
  if thisSound > 0 then
    set bannerSndCast = (newRootName & ",prompt") --thisSound
  else
    put "trouble finding sound cast member in the cast, " & newRootName & ",prompt is missing"
  end if

  -- now we do the reference to the text cast
  set thisText = the number of member (newRootName & ",txt")
  if thisText > 0 then
    set bannerTextCast = thisText

    debug the text of member bannerTextCast
    -- now we are going to put the info on the stage
    set the foreColor of member bannerFieldCast = 255

    put the text of member bannerTextCast into field bannerFieldCast

    -- now play the banner for the first time
    if not noPlay then return playBanner(me)
    else return 0

  else
    put "trouble finding text cast member in the cast, " & newRootName & ",txt is missing"
    return 0
  end if
end


-- this just plays back the current banner sound and text, while animating the sound icon

on playBanner me
  unloadCast (me)
  -- grab a hold of the necessary sprite
  puppetSprite bannerSprite, TRUE
  set oldMem = the memberNum of sprite bannerSprite
  set oldLib = the castLibNum of sprite bannerSprite

  -- now go to it
  if bannerSndCast > 0  then
    -- change the color of the text
    set the foreColor of member bannerFieldCast = textHilite

    -- start it playing
    puppetSound bannerSndCast, 1
    updateStage


    -- now just keep on animating
    set iconPtr = 1

    set lastTime = the timer

    set oldCursor = the cursor of sprite the clickOn
    set the cursor of sprite the clickOn to 0
    updateStage
    -- take away the cursor during animations
    cursor 200

    -- now play back and animate at the same time
    repeat while soundBusy(1)

      if the timer >= lastTime + delay then
        -- change the speaker
        -- put "updating icon..."

        set the castNum of sprite bannerSprite = the number of member (getAt(bannerCastList, iconPtr))

        set iconPtr = iconPtr + 1

        if iconPtr > count(bannerCastList) then
          set iconPtr = 1
        end if

        set lastTime = the timer
      end if
      set the cursor of sprite the clickOn to oldCursor
      updateStage
    end repeat

    -- we are done, now return stuff to normal
    set the foreColor of member bannerFieldCast = 255

    set the member of sprite bannerSprite to member oldMem
    set the castLibNum of sprite bannerSprite to oldLib
    updateStage

    puppetSprite bannerSprite, FALSE

    cursor 0

    -- eat the mouse clicks
    clearEvents(me)
    unloadCast (me)
    updateStage
    return 1
  else
    put "there is no sound in the banner property..."
    cursor 0
    unloadCast (me)
    return -1
  end if

end

-- this just clears out the text for the first time you want to use it

on clearBanner me
  put " " into field bannerFieldCast
  set bannerSndCast = 0
end